(*Tabulka parametrů páry s veličinami:
teplota [°C], tlak [MPa], entropie [J/(kg*K)], entalpie [kJ/kg]*)
tab={{278,6.22,5867,2779},{272.8,5.74,5895,2779},{166.5,0.727,6022,2469},{166.3,0.724,6582,2714},{245,0.72,7073,2943},{36.3,0.0061,7454,2297},{36.3,0.0061,523,152},{36.5,2.5,524,154},{63.6,2,876,268},{90,1.6,1196,380},{114,1.4,1461,479},{160,1.2,1938,674},{184,1.11,2183,783},{185,7.7,2181,788},{223,6.1,2542,960},{278,6.22,5867,2779}};

odbery={{229,2.75,5926,2655},{188,1.21,5980,2535},{123,0.205,7130,2711.6},{96,0.088,7171,2584},{68.7,0.029,7238,2441}};

h=Flatten[Take[tab,All,-1]];(*vyjádření pouze entalpií*)

ho=Flatten[Take[odbery,All,-1]];(*vyjádření pouze entalpií odběrů*)
hk={1199(*272.8°C*),830(*195°C*),703(*166.3°C*),521(*124°C*),419(*100°C*),377(*90°C*),194.7(*46.5°C*)};(*entalpie kondenzátu při daných teplotách*)

(*rovnice pro jednotlivá zařízení:*)

suchostpredSP=0.86;
suchostzaSP=0.982;

rceSP=oSP==(suchostzaSP-suchostpredSP)*(1-oP-oVTO-oTO-oNTO4);
rceP=oP*(h[[2]]-hk[[1]])==(1-oP-oVTO-oTO-oNTO4-oSP)*(h[[5]]-h[[4]]);
rceVTO=oVTO*(ho[[1]]-hk[[2]])+oP*(hk[[1]]-hk[[2]])==h[[15]]-h[[14]];
rceTO=oTO*(ho[[2]]-h[[13]])+(oP+oVTO)*(hk[[2]]-h[[13]])==(1-oTO-oP-oVTO-oSP)*(h[[13]]-h[[12]])+oSP*(h[[13]]-hk[[3]]);
rceNTO4=oNTO4*(h[[3]]-hk[[4]])==(1-oTO-oP-oVTO-oSP)*(h[[12]]-h[[11]]);
rceNTO3=oNTO3*(ho[[3]]-hk[[5]])+oNTO4*(hk[[4]]-hk[[5]])==(1-oTO-oP-oVTO-oSP)*(h[[11]]-h[[10]]);
rceNTO2=oNTO2*(ho[[4]]-hk[[6]])+(oNTO3+oNTO4)*(hk[[5]]-hk[[6]])==(1-oTO-oP-oVTO-oSP-oNTO4-oNTO3-oNTO2)*(h[[10]]-h[[9]]);
rceNTO1=oNTO1*(ho[[5]]-hk[[7]])==(1-oTO-oP-oVTO-oSP-oNTO4-oNTO3-oNTO2)*(h[[9]]-h[[8]]);
rceTBN=0.81*oTBN*(h[[5]]-h[[6]])==(tab[[14]][[2]]-tab[[13]][[2]])*1.13;
(*bezSP: rceSP=oSP==0;rceP=oP*(h[[2]]-hk[[1]])==(1-oP-oVTO-oTO-oNTO4-oSP)*(h[[5]]-h[[3]]);*)
(*bezNTO1: rceNTO2=oNTO2*(ho[[4]]-hk[[6]])+(oNTO3+oNTO4)*(hk[[5]]-hk[[6]])==(1-oTO-oP-oVTO-oSP-oNTO4-oNTO3-oNTO2)*(h[[10]]-h[[8]]);
rceNTO1=oNTO1==0;*)

rce={rceSP,rceP,rceVTO,rceTO,rceNTO4,rceNTO3,rceNTO2,rceNTO1,rceTBN};
promenne={oSP,oP,oVTO,oTO,oNTO4,oNTO3,oNTO2,oNTO1,oTBN};

res=Solve[rce,promenne][[1]](*řešení soustavy rovnic*)

doVT=(1-oP);
doNT=(1-oP-oVTO-oTO-oSP-oTBN-oNTO4);

aVT=doVT*(h[[2]]-ho[[1]])+(doVT-oVTO)*(ho[[1]]-ho[[2]])+(doVT-oVTO-oTO)*(ho[[2]]-h[[3]]);aNT=doNT*(h[[5]]-ho[[3]])+(doNT-oNTO3)*(ho[[3]]-ho[[4]])+(doNT-oNTO3-oNTO2)*(ho[[4]]-ho[[5]])+(doNT-oNTO3-oNTO2-oNTO1)*(ho[[5]]-h[[6]]);a=aVT+aNT/.res;(*určení vykonané práce*)

q=1*(h[[16]]-h[[15]]);(*určení dodaného tepla*)

η=100*(a/q)(*výpočet účinnosti*)

ηmax=100*((tab[[1]][[1]]-tab[[6]][[1]])/(tab[[1]][[1]]+273.15))(*výpočet maximální možné účinnosti*)

(η/(ηmax))*100(*výpočet poměru dosažené a maximální účinnosti*)

P1=3129000.;

P1/q(*výpočet celkového hmotnostního toku*)

(promenne*P1/q)/.res(*výpočet jmenovitých odběrů*)

P1*η/100000(*výpočet vyráběného výkonu*)